PRÁCTICA CERO

CONECTANDO EL MANDO DE PS4 CON LA PLACA ESP32 POR PRIMERA VEZ. Empieza lo interesante

Descripción de la práctica

En esta primera práctica vamos a centrarnos en la conexión del mando de PS4 con la tarjeta ESP32. Son tarjetas microcontroladoras evolucionadas a partir de la famosa placa Arduino, pero con mucha más potencia y una serie de funciones que las tarjetas Arduino más básicas no tenía.

Pasos

La placa ESP32 tiene la capacidad de comunicarse a través de Bluetooth y de Wi-fi. Esto es un avance respecto a las placas Arduino Rev UNO que tenemos en el taller. Para poder tener comunicación inalámbrica con las placas de Arduino necesitaríamos utilizar módulos de comunicación Wi-fi y Bluetooth que habría que conectar a la placa de Arduino a través de varios pines. En las placas ESP32 esto no es necesario porque estos módulos ya están incluidos en su arquitectura.

Para poder conectar el mando PS4 a la placa ESP32, debemos seguir varios pasos:

1) Lo primero que tenemos que hacer, puesto que vamos a programar la placa ESP32 con la IDE de Arduino, es instalar en esta una serie de librerías que vamos a necesitar. En programación las librerías son herramientas para hacer que el desarrollo de software sea más eficiente. Proporcionan fragmentos de código reutilizables que los desarrolladores pueden utilizar para programar de forma rápida y sencilla. Cada librería tiene unas funciones ya programadas por alguien, y al usar una librería en un programa, tendremos acceso a esas funciones sin necesidad de escribirlas nosotros. Por ejemplo, una librería matemática contendrá el código de la función logaritmo, de tal forma que si incluímos esa librería en nuestro programa, podremos hacer logaritmos con solo "llamar" a esa función. En particular nosotros necesitamos dos librerías: PS4Controller.h que contiene las funciones necesarias para poder utilizar el mando de PS4 en este proyecto, y la librería ESP32Servo.h que nos permitirá utilizar el servo motor de forma sencilla con la placa ESP32.

Por otra parte, para poder utilizar la placa ESP32 con la IDE de Arduino, tenemos que incluir en el Board Manager la placa ESP32, de tal forma que, cuando vayamos a seleccionar el puerto y tipo de placa que vamos a utilizar, además de las diferentes placas Arduino nos aparezcan las placas ESP32. Es tan sencillo como entrar en el gestor de placas e instalar la extensión de placas ESP32.

Una vez hecho todo esto, necesario para poder hacer las prácticas y el proyecto, podemos empezar con la conexión del mando de PS4 a la placa ESP32.

2) Para poder establecer la comunicación entre los dos dispositivos, debemos conocer la dirección Mac de la placa ESP32. Esta dirección es un código único que identifica a la placa en las comunicaciones Bluetooth. Para conocerla vamos a utilizar el código GetMacAdress que adjuntamos. Este código, una vez descargado en la placa, lo que hace es enviarnos a través del puerto serie la dirección Mac de la placa. Cada placa tiene su propia dirección que lo identifica y es necesario conocerla para establecer comunicación Bluetooth entre dispositivos.

3) Una vez conocida la dirección Mac del ESP32, debemos introducirla en la memoria del mando PS4. Cuando el mando se conecta con una consola, lo que hace es almacenar en memoria la dirección Mac de dicha consoloa. Nosotros lo que vamos a hacer ahora es forzar al mando a sustituir la dirección Mac de la última consola con la que se conectó por la dirección de la ESP32. Una vez hecho esto, placa y mando estarán emparejados. Para conseguirlo debemos instalar una aplicación que nos permita modificar la dirección Mac almacenada en la memoria del mando PS4. Nosotros utilizaremos la aplicación SixaxisPairTool.

4) Por último vamos a comprobar que todo funciona adecuadamente. Para ello vamos a descargar en la ESP32 el código PruebaPS4 que se adjunta. Este código establece una comunicación serie entre el ESP32 y el ordenador, y nos muestra en el monitor serie la actividad del mando de PS4, si se pulsan los diferentes botones del mando lo podremos ver en tiempo real.

Materiales

• Placa ESP32.
• Mando PS4.

Código

GetMacAdress

// Código para conseguir la dirección Mac de la placa ESP32

//Primero incluimos las librerías que necesitará la ESP32 para correr el programa

#include <PS4Controller.h>

#include <esp_bt_main.h>

#include <esp_bt_device.h>

char str[100]; // Creamos una cadena de caracteres donde se almacenará la dirección Mac de la ESP32

void setup()

{

Serial.begin(115200); // Iniciamos la comunicación serie con el PC con una frecuencia de 115200 baudios (que es la de la ESP32)

PS4.begin(); // Iniciamos la clase PS4, que representa a nuestro mando e identifica todos los eventos que en él ocurrirán.

const uint8_t* address = esp_bt_dev_get_address();

sprintf(str, "ESP32's Bluetooth MAC address is - %02x:%02x:%02x:%02x:%02x:%02x", address[0],address[1],address[2],address[3],address[4],address[5]); // Almacenamos en la cadena la dirección Mac.

}

void loop()

{

Serial.println(str); // Escribe en pantalla la direción almacenada.

}

PruebaPS4

#include <PS4Controller.h>

unsigned long lastTimeStamp = 0; // es una variable que utilizaremos para controlar e.....

void notify() // Esta es la función principàl de este código. Cada vez que ocurra un evento en el mando (cada vez que se preione un botón) se llamará a esta función que lo que hace es mostrar en pantalla los valores de cada uno de los botones del mando PS4.

{

char messageString[200]; // cadena en la que se almacenan los valores de todos los botones del mando

sprintf(messageString, "%4d,%4d,%4d,%4d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d,%3d",

PS4.LStickX(),

PS4.LStickY(),

PS4.RStickX(),

PS4.RStickY(),

PS4.Left(),

PS4.Down(),

PS4.Right(),

PS4.Up(),

PS4.Square(),

PS4.Cross(),

PS4.Circle(),

PS4.Triangle(),

PS4.L1(),

PS4.R1(),

PS4.L2(),

PS4.R2(),

PS4.Share(),

PS4.Options(),

PS4.PSButton(),

PS4.Touchpad(),

PS4.Charging(),

PS4.Audio(),

PS4.Mic(),

PS4.Battery());

if (millis() - lastTimeStamp > 50) // Esto básicamente comprueba que el tiempo transcurrido sea mayor de 50 ms. Si es así se imprime en pantalla la cadena con los valores del mando. Si t< 50 ms no se imprime nada para no saturar la comunicación entre la placa y el PC.

{

Serial.println(messageString);

lastTimeStamp = millis();

}

}

void onConnect() // Cuando se conecta el mando en pantalla aparece el mensaje de "Mando conectado"

{

Serial.println("Mando Conectado!.");

}

void onDisConnect() // Cuando se conecta el mando en pantalla aparece el mensaje de "Mando desconectado"

{

Serial.println("Mando desconectado!.");

}

void setup()

{

Serial.begin(115200); // Se inicia la comunicación serie

PS4.attach(notify); // Se asocia a la clase PS4 la función notify

PS4.attachOnConnect(onConnect); // Se asocia a la clase PS4 la función onConnect

PS4.attachOnDisconnect(onDisConnect); // Se asocia a la clase PS4 la función onDisConnect

PS4.begin(); // Se inicia la clase PS4

Serial.println("Ready.");

}

void loop()

{

}